undefine([AC_TRY_CPP])
undefine([AC_LANG_CPLUSPLUS])
undefine([AC_PROG_RANLIB])

dnl AC_TRY_CPP(INCLUDES, [ACTION-IF-TRUE [, ACTION-IF-FALSE]])
AC_DEFUN(AC_TRY_CPP,
[AC_REQUIRE_CPP()dnl
cat > conftest.$ac_ext <<EOF
[#]line __oline__ "configure"
#include "confdefs.h"
[$1]
EOF
dnl Capture the stderr of cpp.  eval is necessary to expand ac_cpp.
dnl We used to copy stderr to stdout and capture it in a variable, but
dnl that breaks under sh -x, which writes compile commands starting
dnl with ` +' to stderr in eval and subshells.
ac_try="$ac_cpp conftest.$ac_ext >conftest.output 2>conftest.out"
AC_TRY_EVAL(ac_try)
ac_err=`grep -v '^ *+' conftest.out|grep -v Microsoft|grep -v "^conftest.$ac_ext$"`
if test -z "$ac_err"; then
  ifelse([$2], , :, [rm -rf conftest*
  $2])
else
  echo "$ac_err" >&AC_FD_CC
  echo "configure: failed program was:" >&AC_FD_CC
  cat conftest.$ac_ext >&AC_FD_CC
ifelse([$3], , , [  rm -rf conftest*
  $3
])dnl
fi
rm -f conftest*])


dnl AC_LANG_CPLUSPLUS()
AC_DEFUN(AC_LANG_CPLUSPLUS,
[define([AC_LANG], [CPLUSPLUS])dnl
ac_ext=C
# CXXFLAGS is not in ac_cpp because -g, -O, etc. are not valid cpp options.
ac_cpp='$CXXCPP $CPPFLAGS'
#
case ${CXX-g++} in
cl) ac_compile='${CXX-g++} -c $CXXFLAGS $CPPFLAGS -Tp conftest.$ac_ext 1>&AC_FD_CC; mv conftest.obj conftest.o' ;;
*)  ac_compile='${CXX-g++} -c $CXXFLAGS $CPPFLAGS conftest.$ac_ext 1>&AC_FD_CC';;
esac
#
case ${CXX-g++} in
cl) ac_link='${CXX-g++}  -Feconftest $CXXFLAGS $CPPFLAGS $LDFLAGS -Tp conftest.$ac_ext 1>&AC_FD_CC; mv conftest.exe conftest; mv conftest.obj conftest.o' ;;
*)  ac_link='${CXX-g++} -o conftest $CXXFLAGS $CPPFLAGS $LDFLAGS conftest.$ac_ext $LIBS 1>&AC_FD_CC';;
esac
#
cross_compiling=$ac_cv_prog_cxx_cross
])


AC_DEFUN(AC_PROG_RANLIB,
[
case ${CXX-g++} in
cl) AC_CHECK_PROG(RANLIB, ranlib, :, :) ;;
*)  AC_CHECK_PROG(RANLIB, ranlib, ranlib, :) ;;
esac
])