*
macro item_cs_cdf_d0 EPS=-113
* IF EPS=-113, EPS FILE
* IF EPS=-111, PS FILE
igset *
set *
opt *
tit ' '
v/del *
*
IF [EPS]=-113 THEN
f/file 50 item_cs_cdf_d0.eps
ELSEIF [EPS]=-111 THEN
f/file 50 item_cs_cdf_d0.ps
ENDIF
*
meta 50 [EPS]
opt nbox
*
v/cr zero(10) r 10*0
v/cr   cs(10) r
v/cr ecsp(10) r
v/cr ecsm(10) r
v/cr csup(10) r
v/cr cslo(10) r
v/cr ynum(10) r
*
* CDF cross sections and +/- errors at mtop=175 GeV/c**2 
*
v/in   cs(1:6) 7.5 8.5 6.8 8.0 10.1 15.6
*v/in ecsp(1:6) 1.9 4.4 2.3 4.4  4.5 18.6
v/in ecsp(1:6) 1.9 4.4 2.3 4.4  4.5 19
*v/in ecsm(1:6) 1.6 3.4 1.8 3.6  3.6 13.2
v/in ecsm(1:6) 1.6 3.4 1.8 3.6  3.6 13
v/in ynum(1:6) 18 16 15 14 13 12
*
* D0  cross sections and errors     at mtop=173.33 GeV/c**2
*
*v/in   cs(7:10) 5.48 6.26 4.05 8.19
v/in   cs(7:10) 5.5 6.3 4.1 8.2
*v/in ecsp(7:10) 1.76 3.29 2.04 3.49
v/in ecsp(7:10) 1.8 3.3 2.0 3.5
v/co ecsp(7:10) ecsm(7:10)
v/in ynum(7:10) 9 7 6 5
*
vadd      cs ecsp csup
vsubtract cs ecsm cslo
*
set ytic 0.000001
set xval 1000
set xtic -0.3
set yval 0.5
**set vsiz 0.4
set vsiz 0.3
set ndvx 207
*
set ymgu 2.5
set ymgl 2.5
set xmgr 5.5
set xmgl 8
*
set cshi 0.02
set pass 5
set bwid 5
set lwid 5
set xwid 5
set ywid 5
set hwid 5
set pwid 5
*
null 0 20 0 20 
*
* Theory
*
* At top mass 175 GeV/c^2 :
*   Berger et al.               5.4 - 5.5 pb
*   Laenen et al.               4.9 - 5.0 pb
*   Catani et al.               4.7 - 4.8 pb
*
igset txci 5
igset faci 5
*text -1 2 'Theory' 0.4 0 r
text 3.7 0.7 'Theory' 0.4 90 l
v/cr fx(4) r 4.7  4.7  5.5  5.5
v/cr fy(4) r 0.   20.   20.   0. 
text 21 2 '4.7 - 5.5 pb' 0.4 0 l
set fais 1
set fasi -120
farea 4 fx fy
*
igset txci 1
set dmod 1
line 0  4 20  4
line 0 11 20 11
text 10 21.5 'Top Cross Sections' 0.5 0 c
text 10 -2.5 '[s]?tt! (pb)' 0.5 0 c
*
* Plot CDF results
*
set pmci 7
set hcol 7
set txci 7
set dmod 1
igset plci 7
text -1 19 'CDF (m?t!=175 GeV/c^2!)' 0.4 0 r
text -1 $sigma(ynum(1)) 'Combined' 0.4 0 r
text -1 $sigma(ynum(2)) 'DIL' 0.4 0 r
text -1 $sigma(ynum(3)) 'SVX' 0.4 0 r
text -1 $sigma(ynum(4)) 'SLT' 0.4 0 r
text -1 $sigma(ynum(5)) 'HAD' 0.4 0 r
text -1 $sigma(ynum(6)) '[t]-DIL' 0.4 0 r
hplot/symbols cs(1:6) ynum(1:6) 6 21 0.2
DO i=1,6
  line $sigma(cslo([i])) $sigma(ynum([i])) $sigma(csup([i])) $sigma(ynum([i]))
  if [i] >= 4 then
    set dmod 2
  endif
  cst = $sigma(cs([i]))
  if $sigma(MOD(cs([i]),1)) = 0 then
    cstxt = [cst]//'.0+'//$sigma(ecsp([i]))//'-'//$sigma(ecsm([i]))//' pb'
  else
    cstxt = [cst]//'+'//$sigma(ecsp([i]))//'-'//$sigma(ecsm([i]))//' pb'
  endif
  text 21 $sigma(ynum([i])) [cstxt] 0.4 0 l
ENDDO
*
* Plot D0 results
*
set pmci 2
set hcol 2
set txci 2
set dmod 1
igset plci 2
text -1 10 'D0  (m?t!=173 GeV/c^2!)' 0.4 0 r
text -1 $sigma(ynum(7)) 'Combined' 0.4 0 r
text -1 $sigma(ynum(8)) 'Dilepton (with e[n])' 0.4 0 r
text -1 $sigma(ynum(9)) 'L+jets (topological)' 0.4 0 r
text -1 $sigma(ynum(10)) 'L+jets ([m]-tagged)' 0.4 0 r
hplot/symbols cs(7:10) ynum(7:10) 6 20 0.2
DO i=7,10
  line $sigma(cslo([i])) $sigma(ynum([i])) $sigma(csup([i])) $sigma(ynum([i]))
  cst = $sigma(cs([i]))
  ecst = $sigma(ecsp([i]))
  if $sigma(MOD(ecsp([i]),1)) = 0 then
    cstxt = [cst]//'"a#'//[ecst]//'.0 pb'
  else
    cstxt = [cst]//'"a#'//[ecst]//' pb'
  endif
  text 21 $sigma(ynum([i])) [cstxt] 0.4 0 l
ENDDO
*
close 50
return